import ddf.minim.signals.*;
import ddf.minim.*;
import ddf.minim.analysis.*;
import ddf.minim.effects.*;

Minim minim;
AudioInput input;
FFT spectrum;
//
int maxCells = 2000; // max number of cells in the "colony"
float anglefactormin = 0.3; // try an assymetrical range to get more curly shapes
float anglefactormax = 0.7; // or a more constrained range for fewer branches
int numBands = 44; // how many freq bands
int lifeSpan = 500; // how many ticks each cell lives for
int spawnEnergy = 50; // min cell energy to breed
int branchEnergy = 400;
float breedChance = 0.5;
float branchChance = 0.01;
float diameterFactor = 200; // multiplier - diameter = diameterFactor/(band+1)
float ampFactor = 1; // multiplier to get cell wall thickness from spectrum band amplitude
float Damping = 0.99; // damps incoming audio
//
float worldx = 0;
float worldy = 0;

ArrayList Cells = new ArrayList(maxCells);
//ArrayList growCells = new ArrayList(maxCells);
Cell firstCell;

void setup(){
  size(1000,450);
  background(0);
  firstCell = new Cell(400,400,0.0,20,0.3); // x,y,angle,band, branchcurve
  Cells.add(firstCell);
    //
  minim = new Minim(this);
  input = minim.getLineIn(Minim.MONO, 1024);
  spectrum = new FFT(1024,44100);
  spectrum.logAverages(11,4); // make 44 log spaced bands, lowest at 11Hz
  //
}

void draw(){
  
  doSpectrum();
  //background(0);
  noStroke();
  
  fill(0,20);
  rect(0,0,width,height);
  translate(worldx,worldy);
  noFill();
  stroke(255,100);
  smooth();
  for (int i=0; i<Cells.size(); i++){ // check age & breed first
    Cell thisCell = (Cell) Cells.get(i);
    thisCell.checkCell();
  }
  for (int p=0; p<Cells.size(); p++){ // then draw them
    Cell thatCell = (Cell) Cells.get(p);
    thatCell.drawCell();
  }
  if (Cells.size() == 0){ // all dead
    firstCell = new Cell(random(width),random(height),0,int(random(numBands)),0.3);
    Cells.add(firstCell);
  }
}

void doSpectrum(){
  spectrum.forward(input.mix);
}


class Cell{

  float xpos;
  float ypos;
  float parent_angle;
  float branch_curvature;
  float diameter;
  float energy;
  Cell parent;
  //Cell[] children;
  int numkids;
  int numbranches;
  //int maxkids;
  int age;
  int band;

  Cell(float xpos_in, float ypos_in, float parent_angle_in, int band_in, float branch_curvature_in){
    xpos = xpos_in;
    ypos = ypos_in;
    parent_angle = parent_angle_in;
    branch_curvature = branch_curvature_in;
    band = band_in;
    diameter = diameterFactor/(band+1);
    age=0;
    energy=0;
    numkids=0;
    numbranches=0;
  }

  void makeChild(float newangle, float newbranchcurve){
    boolean freespace = true;
    int newband = constrain(band+int(random(-4,4)),0,numBands); // new freq band for the child
    float newdiam = diameterFactor/(newband+1);
    float newx = (xpos+(0.5*(diameter+newdiam)*sin(newangle)));
    float newy = (ypos+(0.5*(diameter+newdiam)*cos(newangle)));
    for (int i=0; i<Cells.size(); i++){
      Cell checkCell = (Cell) Cells.get(i);
      float distance = sqrt(sq(newx-checkCell.xpos)+sq(newy-checkCell.ypos));
      if (distance < ((newdiam+checkCell.diameter)*0.5)){
        freespace = false;
        i = Cells.size();
      }
    }
    if (freespace) {
      Cell newCell = new Cell(newx,newy,newangle,newband,newbranchcurve);
      newCell.parent = this;
      Cells.add(newCell);
      numkids++;
    }
  }

  void drawCell(){
    energy = (energy*Damping)+(spectrum.getAvg(band)*(band+1)*0.05); // get energy from the spectrum band
    if (parent != null) parent.energy += energy*0.003; // pass a bit of energy up to your parent
    //strokeWeight(spectrum.getAvg(band)+0.5); 
    strokeWeight(energy*0.01); 
    ellipse(xpos,ypos,diameter,diameter);   
    //ellipse(xpos,ypos,1,1); 
    
    
  }
  
  void checkCell(){
      age++;    
    if (this != firstCell && Cells.contains(this.parent) == false) {
      Cells.remove(this); // you're dead
      if (parent != null) parent.numkids--;
    } else if (age > lifeSpan && energy < 100){
      Cells.remove(this);
      if (parent != null) parent.numkids--;
    }
     else if (energy > spawnEnergy && Cells.size() < maxCells) { // if you're big enough, there's room to breed, and you're lucky
      float chance = random(1);
      if (numkids == 0 && chance < breedChance){
        makeChild(parent_angle+branch_curvature, branch_curvature+random(-0.05,0.05)); // continue this branch with a small curve mutation
      } else if (chance < branchChance && energy > spawnEnergy*4) {
        makeChild(parent_angle-1.5, branch_curvature+random(-0.2,0.2)); // start a new branch with a mutated curvature
      }
    } 
    
  }
}

void stop()
{
  input.close();
  super.stop();
}

void keyPressed(){
if (keyCode == UP){
  worldy -= 5;
} else if (keyCode == DOWN){
  worldy += 5;
} else if (keyCode == LEFT){
  worldx -= 5;
} else if (keyCode == RIGHT){
  worldx += 5;
}

}